如何 SQL Server 2005 实例之间传输登录和密码
INTRODUCTION
本文介紹如何不同服務(wù)器上的 Microsoft SQL Server 2005 實(shí)例之間傳輸?shù)卿浐兔艽a。
本文, 服務(wù)器 A 和服務(wù)器 B 是不同的服務(wù)器。 此外, 服務(wù)器 A 和 B 服務(wù)器都運(yùn)行 SQL Server 2005。
將數(shù)據(jù)庫(kù)從服務(wù)器 A 上的 SQLServer 實(shí)例移到 B, 服務(wù)器上的 SQLServer 實(shí)例后用戶(hù)可能不能夠登錄到數(shù)據(jù)庫(kù) B 另外服務(wù)器上， 用戶(hù)可能收到以下錯(cuò)誤信息：
對(duì)于用戶(hù) MyUser ' ' 登錄失敗。 （MicrosoftSQLServer、 錯(cuò)誤 18456：）
發(fā)生此問(wèn)題是因?yàn)闆](méi)有您做從服務(wù)器 A 上的 SQLServer 實(shí)例傳輸和密碼登錄到服務(wù)器 B 上的 SQLServer 實(shí)例
要從服務(wù)器 A 上的 SQLServer 實(shí)例傳輸?shù)椒?wù)器 B, 上的 SQLServer 實(shí)例登錄和密碼請(qǐng)按照下列步驟操作：
1.在服務(wù)器 A, 啟動(dòng) SQLServerManagementStudio, 并然后連接到 SQLServer 從中移動(dòng)數(shù)據(jù)庫(kù)的實(shí)例。
2.打開(kāi)新查詢(xún)編輯器窗口, 然后運(yùn)行以下腳本。
USE master
GO
IF OBJECT_ID ('sp_hexadecimal') IS NOT NULL
DROP PROCEDURE sp_hexadecimal
GO
CREATE PROCEDURE sp_hexadecimal
@binvalue varbinary(256),
@hexvalue varchar (514) OUTPUT
AS
DECLARE @charvalue varchar (514)
DECLARE @i int
DECLARE @length int
DECLARE @hexstring char(16)
SELECT @charvalue = '0x'
SELECT @i = 1
SELECT @length = DATALENGTH (@binvalue)
SELECT @hexstring = '0123456789ABCDEF'
WHILE (@i <= @length)
BEGIN
DECLARE @tempint int
DECLARE @firstint int
DECLARE @secondint int
SELECT @tempint = CONVERT(int, SUBSTRING(@binvalue,@i,1))
SELECT @firstint = FLOOR(@tempint/16)
SELECT @secondint = @tempint - (@firstint*16)
SELECT @charvalue = @charvalue +
SUBSTRING(@hexstring, @firstint+1, 1) +
SUBSTRING(@hexstring, @secondint+1, 1)
SELECT @i = @i + 1
END
SELECT @hexvalue = @charvalue
GO
IF OBJECT_ID ('sp_help_revlogin') IS NOT NULL
DROP PROCEDURE sp_help_revlogin
GO
CREATE PROCEDURE sp_help_revlogin @login_name sysname = NULL AS
DECLARE @name sysname
DECLARE @type varchar (1)
DECLARE @hasaccess int
DECLARE @denylogin int
DECLARE @is_disabled int
DECLARE @PWD_varbinary varbinary (256)
DECLARE @PWD_string varchar (514)
DECLARE @SID_varbinary varbinary (85)
DECLARE @SID_string varchar (514)
DECLARE @tmpstr varchar (1024)
DECLARE @is_policy_checked varchar (3)
DECLARE @is_expiration_checked varchar (3)
DECLARE @defaultdb sysname
IF (@login_name IS NULL)
DECLARE login_curs CURSOR FOR
SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM
sys.server_principals p LEFT JOIN sys.syslogins l
ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name <> 'sa'
ELSE
DECLARE login_curs CURSOR FOR
SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM
sys.server_principals p LEFT JOIN sys.syslogins l
ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name = @login_name
OPEN login_curs
FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin
IF (@@fetch_status = -1)
BEGIN
PRINT 'No login(s) found.'
CLOSE login_curs
DEALLOCATE login_curs
RETURN -1
END
SET @tmpstr = '/* sp_help_revlogin script '
PRINT @tmpstr
SET @tmpstr = '** Generated ' + CONVERT (varchar, GETDATE()) + ' on ' + @@SERVERNAME + ' */'
PRINT @tmpstr
PRINT ''
WHILE (@@fetch_status <> -1)
BEGIN
IF (@@fetch_status <> -2)
BEGIN
PRINT ''
SET @tmpstr = '-- Login: ' + @name
PRINT @tmpstr
IF (@type IN ( 'G', 'U'))
BEGIN -- NT authenticated account/group
SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' FROM WINDOWS WITH DEFAULT_DATABASE = [' + @defaultdb + ']'
END
ELSE BEGIN -- SQL Server authentication
-- obtain password and sid
SET @PWD_varbinary = CAST( LOGINPROPERTY( @name, 'PasswordHash' ) AS varbinary (256) )
EXEC sp_hexadecimal @PWD_varbinary, @PWD_string OUT
EXEC sp_hexadecimal @SID_varbinary,@SID_string OUT
-- obtain password policy state
SELECT @is_policy_checked = CASE is_policy_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name
SELECT @is_expiration_checked = CASE is_expiration_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name
SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' WITH PASSWORD = ' + @PWD_string + ' HASHED, SID = ' + @SID_string + ', DEFAULT_DATABASE = [' + @defaultdb + ']'
IF ( @is_policy_checked IS NOT NULL )
BEGIN
SET @tmpstr = @tmpstr + ', CHECK_POLICY = ' + @is_policy_checked
END
IF ( @is_expiration_checked IS NOT NULL )
BEGIN
SET @tmpstr = @tmpstr + ', CHECK_EXPIRATION = ' + @is_expiration_checked
END
END
IF (@denylogin = 1)
BEGIN -- login is denied access
SET @tmpstr = @tmpstr + '; DENY CONNECT SQL TO ' + QUOTENAME( @name )
END
ELSE IF (@hasaccess = 0)
BEGIN -- login exists but does not have access
SET @tmpstr = @tmpstr + '; REVOKE CONNECT SQL TO ' + QUOTENAME( @name )
END
IF (@is_disabled = 1)
BEGIN -- login is disabled
SET @tmpstr = @tmpstr + '; ALTER LOGIN ' + QUOTENAME( @name ) + ' DISABLE'
END
PRINT @tmpstr
END
FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin
END
CLOSE login_curs
DEALLOCATE login_curs
RETURN 0
GO
此腳本 注意 在 master 數(shù)據(jù)庫(kù)中創(chuàng)建兩個(gè)存儲(chǔ)過(guò)程。 兩個(gè)存儲(chǔ)過(guò)程命名為 sp_hexadecimal 存儲(chǔ)過(guò)程和 sp _ help _ revlogin < 存儲(chǔ)過(guò)程。
3.運(yùn)行下列語(yǔ)句。
EXEC sp_help_revlogin
由 sp _ help _ revlogin < 存儲(chǔ)過(guò)程生成輸出腳本是登錄腳本。 此登錄腳本創(chuàng)建具有原始安全標(biāo)識(shí)符 (SID) 和原始密碼登錄。
4.在服務(wù)器 B, 啟動(dòng) SQLServerManagementStudio, 并再連接到的數(shù)據(jù)庫(kù)移動(dòng)到 SQLServer 實(shí)例。
要點(diǎn) 之前請(qǐng)您轉(zhuǎn)到步驟 5, 查閱 " 備注 " 部分中信息。
5.打開(kāi)新查詢(xún)編輯器窗口, 并運(yùn)行步驟 3 中生成輸出腳本。
批注
對(duì)實(shí)例 B： 服務(wù)器上運(yùn)行該輸出腳本之前檢查下列信息
?仔細(xì)查看腳本輸出。 如果服務(wù)器 A 和 B 服務(wù)器位于不同域, 您需要修改輸出腳本。 然后, 您需要用新域名 LOGIN CREATETABLE 語(yǔ)句中替換原始域名稱(chēng)。 集成登錄授予新域中訪(fǎng)問(wèn)原域中沒(méi)有相同 SID 作為登錄。 因此, 用戶(hù)是從這些登錄中孤立出去。 有關(guān)如何解決這些孤立用戶(hù), 請(qǐng)單擊下列文章編號(hào)以查看 Microsoft 知識(shí)庫(kù)中相應(yīng)：
240872 (http://support.microsoft.com/kb/240872/) 如何運(yùn)行 SQLServer 的服務(wù)器之間移動(dòng)數(shù)據(jù)庫(kù)時(shí)解決權(quán)限問(wèn)題
如果服務(wù)器 A 和 B 服務(wù)器位于同一域, 使用相同的 SID。 因此, 用戶(hù)是不容易被孤立。
?由使用加密密碼, 輸出腳本中創(chuàng)建登錄。 這是因?yàn)榇嬖?LOGIN CREATETABLE 語(yǔ)句中 HASHED 參數(shù)。 該參數(shù)指定散， 是已經(jīng)列是 PASSWORD 參數(shù)后輸入該密碼。
?通過(guò)默認(rèn), 可只是 sysadmin 固定服務(wù)器角色成員從 sys.server_principals 視圖運(yùn)行 SELECT 語(yǔ)句。 用戶(hù)無(wú)法創(chuàng)建或運(yùn)行輸出腳本除非屬于 sysadmin 固定服務(wù)器角色授予對(duì)用戶(hù), 必要權(quán)限。
?本文中步驟執(zhí)行不傳輸用于特定登錄默認(rèn)數(shù)據(jù)庫(kù)信息。 這是因?yàn)槟J(rèn)數(shù)據(jù)庫(kù)服務(wù)器 B 上可能不總是存在 由登錄名和默認(rèn)數(shù)據(jù)庫(kù)中傳遞作為參數(shù)來(lái)定義默認(rèn)數(shù)據(jù)庫(kù)為登錄, 使用 ALTERDATABASE LOGIN 語(yǔ)句。
?服務(wù)器 A 的排序順序可能區(qū)分大小寫(xiě), 并且可能區(qū)分大小寫(xiě)排序次序的服務(wù)器 B。 此例, 用戶(hù)必須鍵入作為大寫(xiě)字母?jìng)魉偷卿浐竺艽a和密碼以服務(wù)器 B 上實(shí)例中所有字母
或者, 服務(wù)器 A 的排序順序可能是區(qū)分大小寫(xiě), 并且可能區(qū)分大小寫(xiě)排序次序的服務(wù)器 B。 通過(guò)登錄和密碼， 除非滿(mǎn)足下列條件之一是傳輸?shù)椒?wù)器 B 上實(shí)例此時(shí), 用戶(hù)無(wú)法登錄:
?原始密碼包含沒(méi)有字母。
?所有原始密碼中字母是大寫(xiě)。
服務(wù)器 A 和服務(wù)器 B 的排序順序可能區(qū)分大小寫(xiě), 或者可能是區(qū)分大小寫(xiě)排序次序的服務(wù)器 A 和服務(wù)器 B。 不會(huì)在這些情況下, 用戶(hù)遇到問(wèn)題。
?登錄服務(wù)器 B 上實(shí)例已經(jīng)處于可能有一個(gè)名稱(chēng)， 等同于輸出腳本中一個(gè)名稱(chēng)。 在這種情況下, B： 服務(wù)器上實(shí)例上運(yùn)行輸出腳本時(shí)收到以下錯(cuò)誤信息
msg 15025, 級(jí)別 16, 1, 狀態(tài)行 1
服務(wù)器 ' MyLogin ' 主體已存在。
同樣, 登錄服務(wù)器 B 上實(shí)例已經(jīng)處于可能與 SID 輸出腳本中一樣， SID。 在這種情況下, B： 服務(wù)器上實(shí)例上運(yùn)行輸出腳本時(shí)收到以下錯(cuò)誤信息
msg 15433, 級(jí)別 16, 1, 狀態(tài)行 1
提供參數(shù) sid 正在使用。
因此, 必須執(zhí)行以下操作：
1.仔細(xì)查看腳本輸出。
2.檢查該實(shí)例中的服務(wù)器 B 上 sys.server_principals 視圖內(nèi)容
3.相應(yīng)地解決這些錯(cuò)誤消息。
?在 SQL Server 2005, 用于登錄 SID 用于作為基礎(chǔ)實(shí)現(xiàn)數(shù)據(jù)庫(kù)級(jí)訪(fǎng)問(wèn)。 登錄服務(wù)器上兩個(gè)不同數(shù)據(jù)庫(kù)中可能有兩個(gè)不同的 SID。 此例, 登錄只能訪(fǎng)問(wèn)數(shù)據(jù)庫(kù)具有 SID 匹配 SID sys.server_principals 視圖中。 如果是從兩個(gè)不同服務(wù)器合并兩個(gè)數(shù)據(jù)庫(kù)可能會(huì)發(fā)生此問(wèn)題。 要解決此問(wèn)題, 通過(guò) DROPUSER 語(yǔ)句具有 SID 匹配數(shù)據(jù)庫(kù)中手動(dòng)刪除登錄。 再次通過(guò) CREATE USER 語(yǔ)句然后, 添加登錄。
from: http://support.microsoft.com/kb/918992/
轉(zhuǎn)載于:https://www.cnblogs.com/emanlee/archive/2007/08/14/855113.html
總結(jié)
以上是生活随笔為你收集整理的如何 SQL Server 2005 实例之间传输登录和密码的全部?jī)?nèi)容，希望文章能夠幫你解決所遇到的問(wèn)題。
- 上一篇： 淘宝上退货上门取件贵吗？跟自己上门去寄相
- 下一篇： 从EAI到SOA