1.VLOOKUP基礎(chǔ)用法

VLOOKUP 函數(shù)表示：
= VLOOKUP (你想要查找的內(nèi)容，要查找的位置，包含要返回的值的區(qū)域中的列號(hào)，返回近似或精確匹配-表示為 1/TRUE 或 0/假)。

第一參數(shù)：找什么(或者說按什么查找)，按業(yè)務(wù)員查找，所以輸入D2
第二參數(shù)：在哪找，數(shù)據(jù)源區(qū)域在A:B列，所以輸入$A$2:$B$12
第三參數(shù)：找到后返回第幾列，我們要查找的是銷售額，銷售額位于B列，即第二參數(shù)中的第二列，所以輸入2
第四參數(shù)：這里要精確查找，所以輸入0

2.VLOOKUP函數(shù)多條件查找

如果有多個(gè)條件要同時(shí)滿足，可以在數(shù)據(jù)源左側(cè)創(chuàng)建一個(gè)輔助列，將多個(gè)條件用&符號(hào)連接起來作為條件查找列。
輸入以下數(shù)組公式，按Ctrl+Shfit+Enter組合鍵結(jié)束輸入。=VLOOKUP(E2&F2,If({1,0},$A$2:$A$12&$B$2:$B$12,$C$2:$C$12),2,0)

這個(gè)公式是數(shù)組公式，如果直接按Enter鍵輸入會(huì)返回#N/A錯(cuò)誤值。

數(shù)據(jù)查找范圍也必須是Sheet2中的AB兩列，這樣才能被找到，由于查找數(shù)據(jù)的條件是A2&B2兩個(gè)單元格的內(nèi)容，但是此二單元格又是獨(dú)立的，因此，要想構(gòu)造查找范圍，也必須把Sheet2中的AB兩列結(jié)合起來，那就構(gòu)成了Sheet2!$A$2:$A$12&Sheet2!$B$2:$B$12;相當(dāng)于AB兩列數(shù)據(jù)組成一列數(shù)據(jù)。

IF({1,0},相當(dāng)于IF({True,False}，用來構(gòu)造查找范圍的數(shù)據(jù)的。
公式中查找區(qū)域?yàn)?IF 數(shù)組條件，數(shù)組由 1 和 0 組成，1 表示 True(真)，0 表示 False(假)；執(zhí)行公式時(shí)，先從數(shù)組中取 1，由于 1 為真，所以從 C2:C9中返回一個(gè)值；然后再從數(shù)組中取 0，由于 0 為假，所以從 B2:B9中返回一個(gè)值；如此反復(fù)，直到遍歷完 C2 到 C9 與 B2 到 B9。
整個(gè)IF({1,0},Sheet2!$A$2:$A$12&Sheet2!$B$2:$B$12,Sheet2!$C$2:$C$12)區(qū)域，就形成了一個(gè)數(shù)組，里面存放兩列數(shù)據(jù)。
第一列是Sheet2AB兩列數(shù)據(jù)的結(jié)合，第二列數(shù)據(jù)是Sheet2!$C$2:$C$12。

{=VLOOKUP(A2&B2,IF({1,0},Sheet2!$A$2:$A$12&Sheet2!$B$2:$B$12,Sheet2!$C$2:$C$12),2,FALSE)}中的數(shù)字2，代表的是返回?cái)?shù)據(jù)區(qū)域中的第二列數(shù)據(jù)。結(jié)果剛好就是Sheet2的C列，即第三列。因?yàn)樵贗F({1,0}公式中，Sheet2中的AB兩列，已經(jīng)被合并成為一列了，所以，Sheet2中的第三列C列，自然就成為序列2的列編號(hào)了，所以，完整的公式中，2代表的就是要返回第幾列的數(shù)據(jù)。

A12&B12 是要查找的值，A12 與 B12 用連接符號(hào) & 連接起來，結(jié)果為“格子85”；查找區(qū)域的條件同樣用 {1,0}數(shù)組條件；公式執(zhí)行時(shí)，先取 1，由于 1 為真，所以從 D2:D9&E2:E9 中返回一個(gè)連結(jié)值(例如 D2&E2)；然后取 0，由于 0 是假，所以從 B2:B9 中取一個(gè)值取來；如此反復(fù)，直到遍歷完 D2&E2 到 D9&E9 與 B2 到 B9。

3.VLOOKUP函數(shù)查找返回多列數(shù)據(jù)

選中H2:K5單元格區(qū)域，輸入以下公式后按Ctrl+Enter組合鍵。
注意是組合鍵同時(shí)按下，而不要只按Enter鍵!=VLOOKUP($G2,$A$2:$E$12,COLUMN(B1),0)

column(b1) 表示 B1所在的列號(hào) 也就是2

4.VLOOKUP函數(shù)從右向左查找

=VLOOKUP(E2,IF({1,0},$B$2:$B$12,$A$2:$A$12),2,0)

5.VLOOKUP函數(shù)按數(shù)據(jù)所處區(qū)間劃分等級(jí)

借助模糊查找VLOOKUP只選比查找值小的那一個(gè)=VLOOKUP(B2,{0,"D";60,"C";80,"B";90,"A"},2)
或=LOOKUP(A1,{0,60,80,90},{"D","C","B","A"})

6.VLOOKUP函數(shù)使用通配符模糊查找

=VLOOKUP("*強(qiáng)*",$A$2:$B$12,2,0)

通配符星號(hào)*通配任意個(gè)字符，問號(hào)?通配單一字符，VLOOKUP函數(shù)支持通配符的用法僅在精確查找模式下，即第四參數(shù)必須為0或者FALSE，如果在模糊查找模式下，那么VLOOKUP函數(shù)是不支持使用通配符的。

7.VLOOKUP函數(shù)多層級(jí)條件嵌套查找

=VLOOKUP(D2,$A$2:$B$8,2)

注意VLOOKUP函數(shù)省略了第四參數(shù)，也就是進(jìn)行模糊查詢模式。

8.VLOOKUP函數(shù)按指定次數(shù)重復(fù)數(shù)據(jù)

輸入以下數(shù)組公式后按Ctrl+Shfit+Enter結(jié)束輸入。=IFERROR(VLOOKUP(ROW(A1),IF({1,0},SUBTOTAL(9,OFFSET(A$2,,,ROW($1:$3))),B$2:B$4),2,),D)

9.VLOOKUP函數(shù)返回查找到的多個(gè)值

輸入以下數(shù)組公式，按Ctrl+Shift+Enter組合鍵結(jié)束輸入。=INDEX(B:B,SMALL(IF(A$2:A$11=D$2,ROW($2:$11),4^8),ROW(A1)))&""

這是經(jīng)典的一對(duì)多查找時(shí)使用的INDEX+SMALL+IF組合。

用VLOOKUP函數(shù)的公式，我也給出，E2輸入數(shù)組公式，按Ctrl+Shift+Enter組合鍵結(jié)束輸入。=IF(COUNTIF(A$2:A$11,D$2)

10.VLOOKUP函數(shù)在合并單元格中查找

=VLOOKUP(F2,OFFSET(B1:C1,MATCH(E2,A2:A10,),,3),2,)

11.VLOOKUP函數(shù)提取字符串中的數(shù)值

在B2輸入以下數(shù)組，按Ctrl+Shift+Enter組合鍵結(jié)束輸入。=VLOOKUP(9E+307,MID(A2,MIN(IF(ISNUMBER(--MID(A2,ROW($1:$99),1)),ROW($1:$99))),ROW($1:$99))*{1,1},2)

12.VLOOKUP函數(shù)轉(zhuǎn)換數(shù)據(jù)行列結(jié)構(gòu)

選中P5:T8單元格區(qū)域，輸入以下區(qū)域數(shù)組公式，按Ctrl+Shift+Enter組合鍵結(jié)束輸入。=VLOOKUP("*",$A$2:$T$2,((ROW(1:4)-1)*5+COLUMN(A:E)),0)

13.合并同類項(xiàng)

=B2&IFERROR("、"&VLOOKUP(A2,A3:C$11,3,0),"")

總結(jié)

以上是生活随笔為你收集整理的excel中vlookup函数的使用方法_EXCEL中查找匹配函数VLOOKUP使用技巧的全部內(nèi)容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網(wǎng)站內(nèi)容還不錯(cuò)，歡迎將生活随笔推薦給好友。