（实模式+保护模式）模式切换的过程步骤（代码+文字解析）
【0】寫在前面
文末的個人總結是干貨，前面代碼僅供參考的，且source code from orange’s implemention of a os.
; ==========================================
; pmtest2.asm
; 編譯方法：nasm pmtest2.asm -o pmtest2.com
; ==========================================
%include "pm.inc" ; 常量, 宏, 以及一些說明
org 0100h
jmp LABEL_BEGIN
；全局描述符表定義
[SECTION .gdt]
; GDT
; 段基址, 段界限 , 屬性
LABEL_GDT: Descriptor 0, 0, 0 ; 空描述符
LABEL_DESC_NORMAL: Descriptor 0, 0ffffh, DA_DRW ; Normal 描述符
LABEL_DESC_CODE32: Descriptor 0, SegCode32Len-1, DA_C+DA_32; 非一致代碼段, 32
LABEL_DESC_CODE16: Descriptor 0, 0ffffh, DA_C ; 非一致代碼段, 16
LABEL_DESC_DATA: Descriptor 0, DataLen-1, DA_DRW ; Data
LABEL_DESC_STACK: Descriptor 0, TopOfStack, DA_DRWA+DA_32; Stack, 32 位
LABEL_DESC_TEST: Descriptor 0500000h, 0ffffh, DA_DRW
LABEL_DESC_VIDEO: Descriptor 0B8000h, 0ffffh, DA_DRW ; 顯存首地址
; GDT 結束
GdtLen equ $ - LABEL_GDT ; GDT長度
GdtPtr dw GdtLen - 1 ; GDT界限
dd 0 ; GDT基地址
;GDT 選擇子定義
SelectorNormal equ LABEL_DESC_NORMAL - LABEL_GDT
SelectorCode32 equ LABEL_DESC_CODE32 - LABEL_GDT
SelectorCode16 equ LABEL_DESC_CODE16 - LABEL_GDT
SelectorData equ LABEL_DESC_DATA - LABEL_GDT
SelectorStack equ LABEL_DESC_STACK - LABEL_GDT
SelectorTest equ LABEL_DESC_TEST - LABEL_GDT
SelectorVideo equ LABEL_DESC_VIDEO - LABEL_GDT
; END of [SECTION .gdt]
;數據段定義
[SECTION .data1] ; 數據段
ALIGN 32
[BITS 32]
LABEL_DATA:
SPValueInRealMode dw 0
; 字符串
PMMessage: db "In Protect Mode now. ^-^", 0 ; 在保護模式中顯示 ;Mine【后面的零作為字符串的結束標志，Line189、232的test會用到】
OffsetPMMessage equ PMMessage - $$ ; Mine【$$ == LABEL_DATA 的基地址，相對于 LABEL_DATA 的偏移地址】
StrTest: db "ABCDEFGHIJKLMNOPQRSTUVWXYZ", 0 ;Mine【后面的零作為字符串的結束標志】
OffsetStrTest equ StrTest - $$
DataLen equ $ - LABEL_DATA
; END of [SECTION .data1]
；全局堆棧段
[SECTION .gs]
ALIGN 32
[BITS 32]
LABEL_STACK:
times 512 db 0
TopOfStack equ $ - LABEL_STACK - 1
; END of [SECTION .gs]
；16位代碼段， CPU運行在實模式下，為什么只有在16位代碼段下才能修改GDT中的值；
[SECTION .s16] ; Mine【為從實模式跳轉到保護模式所做的準備工作】
[BITS 16]
LABEL_BEGIN:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, 0100h
; 下一行指令的解說：
; 待會要跳回到實模式，這里是保存跳轉前的相關 value
; mov [label_backto_real + 3], ax, 這是在代碼已經加載到了內存之后再執行的，為什么加上3，一位jmp指令占用3個字節， 而jmp后面跟著跳轉地址；
; 他的作用是在段基地址存儲單元中去重新設置新值 去 覆蓋原先的段基地址，作者真心很是聰明啊。
mov [LABEL_GO_BACK_TO_REAL+3], ax
mov [SPValueInRealMode], sp ; Mine【保存sp，然后返回實模式后，再將sp取出來】
；初始化 16 位代碼段描述符
mov ax, cs
movzx eax, ax
shl eax, 4
add eax, LABEL_SEG_CODE16
mov word [LABEL_DESC_CODE16 + 2], ax
shr eax, 16
mov byte [LABEL_DESC_CODE16 + 4], al
mov byte [LABEL_DESC_CODE16 + 7], ah
；初始化 32 位代碼段描述符
xor eax, eax
mov ax, cs
shl eax, 4
add eax, LABEL_SEG_CODE32
mov word [LABEL_DESC_CODE32 + 2], ax
shr eax, 16
mov byte [LABEL_DESC_CODE32 + 4], al
mov byte [LABEL_DESC_CODE32 + 7], ah
；初始化數據段描述符
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_DATA ; Mine【數據段的基址便是 LABEL_DATA 的物理地址
; 所以 OffsetStrTest 既是字符串相對于 LABEL_DATA 的偏移地址，也是其在數據段的偏移 】
mov word [LABEL_DESC_DATA + 2], ax
shr eax, 16
mov byte [LABEL_DESC_DATA + 4], al
mov byte [LABEL_DESC_DATA + 7], ah
；初始化堆棧段描述符
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_STACK
mov word [LABEL_DESC_STACK + 2], ax
shr eax, 16
mov byte [LABEL_DESC_STACK + 4], al
mov byte [LABEL_DESC_STACK + 7], ah
; 為加載 GDTR 作準備，填充GDT基地址的數據結構
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_GDT ; eax <- gdt 基地址
mov dword [GdtPtr + 2], eax ; [GdtPtr + 2] <- gdt 基地址
; 加載 GDTR
lgdt [GdtPtr]
; 關中斷
cli
; 打開地址線A20
in al, 92h
or al, 00000010b
out 92h, al
; 準備切換到保護模式， PE位置1
mov eax, cr0
or eax, 1
mov cr0, eax
; 真正進入保護模式
jmp dword SelectorCode32:0 ; 執行這一句會把 SelectorCode32 裝入 cs, 并跳轉到 Code32Selector:0 處
; 從保護模式跳回到實模式就到了這里（注意：從保護模式跳轉到實模式，即本標識符下，本標識符是存在于 初始化描述符的16位代碼段的末尾的）
LABEL_REAL_ENTRY:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, [SPValueInRealMode]
; 關閉 A20 地址線
in al, 92h ;
and al, 11111101b
out 92h, al ; /
sti ; 開中斷
mov ax, 4c00h ; `.
int 21h ; / 回到 DOS
; END of [SECTION .s16]
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 32 位代碼段. 由實模式跳入
[SECTION .s32]
[BITS 32]
LABEL_SEG_CODE32:
mov ax, SelectorData
mov ds, ax ; 數據段選擇子
mov ax, SelectorTest
mov es, ax ; 測試段選擇子
mov ax, SelectorVideo
mov gs, ax ; 視頻段選擇子
mov ax, SelectorStack ; Mine【改變了ss和esp， 則在32位代碼段中所有的堆棧操作將會在新增的堆棧段中進行】
mov ss, ax ; 堆棧段選擇子
mov esp, TopOfStack
; 下面顯示一個字符串（此處代碼有省略）
mov ah, 0Ch ; 0000: 黑底 1100: 紅字
xor esi, esi
xor edi, edi
mov esi, OffsetPMMessage ; 源數據偏移
mov edi, (80 * 10 + 0) * 2 ; 目的數據偏移。屏幕第 10 行, 第 0 列。
cld
.1:
lodsb ; Mine【lodsb、lodsw：把DS:SI指向的存儲單元中的數據裝入AL或AX，然后根據DF標志增減SI】
test al, al ; Mine【1. test ax，100b 將 ax的 值 和 100b進行“與”操作 ，但不改變ax本身
; 2. 若與操作的結果為零則ZF置位】
jz .2
mov [gs:edi], ax
add edi, 2
jmp .1
.2: ; 顯示完畢
call DispReturn ; Mine【call == push ip ; jmp near ptr 標號】
call TestRead ; Mine【先讀出數據】
call TestWrite ; Mine【再寫入數據】
call TestRead ; Mine【再次讀出數據】
; 到此停止，跳入16位代碼段
jmp SelectorCode16:0 ; Mine【Line31，Line80 已經初始化LABEL_DESC_CODE16，保存著LABEL_SEG_CODE16的基地址 】
SegCode32Len equ $ - LABEL_SEG_CODE32
; END of [SECTION .s32]
; 16 位代碼段. 由 32 位代碼段跳入, 跳出后到實模式(LABEL_REAL_ENTRY)
[SECTION .s16code]
ALIGN 32
[BITS 16]
LABEL_SEG_CODE16:
; 跳回實模式:
mov ax, SelectorNormal ; Mine【 選擇子 SelectorNormal 是對描述符 LABEL_DESC_NORMAL 的索引 】
mov ds, ax
mov es, ax
mov fs, ax
mov gs, ax
mov ss, ax
mov eax, cr0
and al, 11111110b ; Mine【cr0的最后一位PE位置為0，進入實模式】
mov cr0, eax
LABEL_GO_BACK_TO_REAL:
jmp 0:LABEL_REAL_ENTRY ; 段地址會在程序開始處被設置成正確的值
Code16Len equ $ - LABEL_SEG_CODE16
; END of [SECTION .s16code]
總結： （從實模式》》保護模式》》實模式）模式切換的過程步驟：（干貨）
（Attention：我們依照程序執行過程的跳轉步驟來對內存內容進行解析）
（1） org 0100， 告訴編譯器程序運行時，要加載到偏移地址0100處；jmp LABEL_BEGIN 跳入到16位代碼段（實模式）進行各個數據段，代碼段，堆棧段的初始化，最后跳入到保護模式；
（2）GDT初始化（定義段描述符 + 定義GDTR的數據結構 + 定義GDT選擇子）：
2.1）定義全局描述符表GDT表項，即定義需要的段描述符，數據段和代碼段描述符數據結構如下：
2.2）定義GDTR全局描述符的數據結構并賦值，GDTR的數據結構如下：
2.3）定義GDT選擇子：有多少個描述符表項，就有多少個選擇子，選擇子用于記錄描述符相對于GDT基地址的偏移地址，因為GDT的基地址和界限是保存在全局描述符寄存器GDTR中的，我們可以通過GDTR找到GDT基地址，然后通過選擇子找到對應的偏移地址，從而找到對應的段描述符的基地址+界限（偏移量）+屬性，而描述符基地址的值又記錄了各個代碼段或數據段的基地址，這樣我們就可以通過選擇子來索引到具體的代碼段和數據段；
（3）數據段 + 堆棧段的定義
（4）16位代碼段（實模式下）的定義：
4.1）設置代碼運行環境，即給相關寄存器賦值；
4.2）初始化16位代碼段描述符 + 32位代碼段描述符 + 堆棧段描述符 +數據段描述符；
4.3）初始化全局描述符表寄存器GDTR的內容，因為其基地址還沒有初始化， 然后通過lgdt [GdtPtr]，將內存中GDTR的內容加載到GDTR中，重點在于保存 GDT的基地址；
4.4）關中斷， 即設置CPU不響應任何其他的外部中斷，因為CPU現在的時間片只屬于當前加載的程序；
4.5）打開地址線A20； 至于為什么要打開，呵呵，參見：http://blog.csdn.net/pacosonswjtu/article/details/48005813
4.6）將CR0的 PE 位置1；PE位==1，表明CPU運行在保護模式下；（這是準備切換到保護模式階段），CR0的數據結構如下：
4.7）跳轉到保護模式： jmp dword SelectorCode32:0 ，這里的代碼指提供了選擇子，（2.3）末部分，已經說明了為什么通過選擇子就可以索引到 32位代碼段 LABEL_SEG_CODE32；（這就是從實模式跳入保護模式）
（5）32位代碼段（由實模式跳入，即保護模式）的定義
5.1）將對應選擇子賦值到 對應寄存器， 即設置 任務代碼的 運行環境，不得不提的是 本段代碼還改變了ss和esp， 則在32位代碼段中所有的堆棧操作將會在新增的堆棧段中進行；
5.2）做任務，我們這里是打印一串字符串；
5.3）任務做完后，跳轉到16位代碼段，因為從保護模式跳回實模式，只能從16位代碼段中跳回；（這個，到底是因為什么，我也說不清楚）
（6）調回到實模式的16位代碼段（我們干脆叫它為過渡的16位代碼段， 與模塊（4）做個區別）
6.1）加載一個描述符選擇子，說是要實現從32位代碼段返回時cs 高速緩沖寄存器中的屬性符合實模式的要求，（具體的，我這里也沒有懂）
6.2）將CR0的 PE 位置0；PE位==0，表明CPU運行在實模式下；（這是準備切換到實模式階段），參見4.6所附圖片；
6.3）真正跳轉到實模式：LABEL_GO_BACK_TO_REAL: jmp 0:LABEL_REAL_ENTRY ; 這里的0 純粹是個幌子，我理解的是，它就是個占位符而已，因為在16位代碼段初始化的時候，已經將它的值設定為 跳轉前的 cs（段基址）值了，即 mov [LABEL_GO_BACK_TO_REAL+3], ax；
【7】跳回到16位代碼段（實模式）的定義
7.1）該段代碼定義在（5）代碼區域的末尾，因為，它們都是實模式下的運行環境；
7.2）初始化寄存器的值，設置運行環境；
7.3）重新設置 堆棧指針sp 的值，這個值早在16位代碼段初始化的時候，已經將它的值 暫存在變量里了，這里只是將它恢復到原來的值而已，即 mov [SPValueInRealMode], sp；
7.4）關閉A20地址線， 為什么要關閉，參見：http://blog.csdn.net/pacosonswjtu/article/details/48005813
7.5）開中斷；
7.6）產生中斷信號，回到DOS；
版權聲明：本文為博主原創文章，未經博主允許不得轉載。
總結
以上是生活随笔為你收集整理的（实模式+保护模式）模式切换的过程步骤（代码+文字解析）的全部內容，希望文章能夠幫你解決所遇到的問題。
- 上一篇： 网页抓取：PHP实现网页爬虫方式小结
- 下一篇： 银行各交易渠道的清算方式